// Confetti02
// Dave Bollinger
// http://www.davebollinger.com
// for Processessing 0109 Beta

/**
Click and drag to spawn confetti.<br>
Press space to toggle clear-screen/overdraw mode.<br>
Press 'c' to toggle color/gray mode.<br>
Press 'p' to select random palette.<br>
Press 's' to toggle scale reduction.<br>
*/

ArrayList things;
MultiPalette pal;
boolean bClearScreen = false;
boolean bScaleReduce = true;
boolean bUseColor = true;

void setup() {
  size(360,360);
  smooth();
  things = new ArrayList();
  pal = new MultiPalette("palettes.jpg");
  pal.select();
  background(255);
  fill(255);
}

void draw() {
  if (bClearScreen)
    background(255);
  if (mousePressed && (mouseButton==LEFT))
    spawn();
  if (things.size() > 0) {
    for (int i=0, sz=things.size(); i<sz; i++) {
      ConfettiBase c = (ConfettiBase)things.get(i);
      c.move();
      if (c.alive())
        c.draw();
      else {
        things.remove(c);
        i--;
        sz--;
      }
    }
  }
}
  
void keyPressed() {
  if (key=='`') saveFrame("frame.tga");
  if (key==' ') bClearScreen = !bClearScreen;
  if (key=='c') bUseColor = !bUseColor;
  if (key=='s') bScaleReduce = !bScaleReduce;
  if (key=='p') pal.select();
}

void spawn() {
  int which = (int)(random(8));
  switch(which) {
    case 0 : things.add( new ConfettiRectangle(mouseX,mouseY) ); break;
    case 1 : things.add( new ConfettiTriangle(mouseX,mouseY) );  break;
    case 2 : things.add( new ConfettiParallelogram(mouseX,mouseY) ); break;
    case 3 : things.add( new ConfettiHexagon(mouseX,mouseY) ); break;
    case 4 : things.add( new ConfettiPentagon(mouseX,mouseY) ); break;
    case 5 : things.add( new ConfettiStar(mouseX,mouseY) ); break;
    case 6 : things.add( new ConfettiBoomerang(mouseX,mouseY) ); break;
    case 7 : things.add( new ConfettiShuriken(mouseX,mouseY) ); break;
  } 
}

class ConfettiBase {
  float x, y;
  float ox, oy;
  float vel, dvel, ddvel;
  float ang, dang, ddang;
  float t;
  float wid,hei;
  color c;
  ConfettiBase(float _x, float _y) {
    x = _x;
    y = _y;
    t = 0.0;
    wid = random(1.0,20.0);
    hei = random(1.0,20.0);
    c = (bUseColor) ? pal.get() : color(0);
    vel = random(1.0,4.0);
    dvel = random(0.001,0.01);
    ddvel = random(0.0001,0.001);
    ang = random(-PI,PI);
    dang = random(-0.01,0.01);
    ddang = random(-0.001,0.001);
  }
  boolean alive() { return (t < 1.0); }
  void move() {
    ox = x;
    oy = y;
    dang += ddang;
    ang += dang;
    dvel += ddvel;
    vel += dvel;
    vel *= 0.9;
    x += vel * cos(ang);
    y += vel * sin(ang);
    t += 0.01;
  };
  void draw() {
    stroke(red(c), green(c), blue(c), 255f-t*255f);
    fill(255, 255-t*255f);
    pushMatrix();
    translate(x,y);
    float theta = atan2(y-oy,x-ox);
    rotate(theta);
    if (bScaleReduce)
      scale(1.0-t*0.9);
    shape();
    popMatrix();
  };
  void shape() {
  }
}


class ConfettiRectangle extends ConfettiBase {
  ConfettiRectangle(float _x, float _y) { super(_x,_y); } 
  void shape() {
    beginShape(POLYGON);
    vertex(-wid,-hei);
    vertex(wid,-hei);
    vertex(wid,hei);
    vertex(-wid,hei);
    vertex(-wid,-hei);
    endShape();
  }
}

class ConfettiTriangle extends ConfettiBase {
  ConfettiTriangle(float _x, float _y) { super(_x,_y); } 
  void shape() {
    beginShape(POLYGON);
    vertex(-wid/2,-hei);
    vertex(wid,0);
    vertex(-wid/2,hei);
    vertex(-wid/2,-hei);
    endShape();
  }
}

class ConfettiParallelogram extends ConfettiBase {
  ConfettiParallelogram(float _x, float _y) { super(_x,_y); } 
  void shape() {
    beginShape(POLYGON);
    vertex(-wid,-hei);
    vertex(-wid/2,hei);
    vertex(wid,hei);
    vertex(wid/2,-hei);
    vertex(-wid,-hei);
    endShape();
  }
}

class ConfettiPentagon extends ConfettiBase {
  ConfettiPentagon(float _x, float _y) { super(_x,_y); } 
  void shape() {
    beginShape(POLYGON);
    vertex(-wid/2,-hei/2);
    vertex(wid/2,-hei);
    vertex(wid,0);
    vertex(wid/2,hei);
    vertex(-wid/2,hei/2);
    vertex(-wid/2,-hei/2);
    endShape();
  }
}

class ConfettiHexagon extends ConfettiBase {
  ConfettiHexagon(float _x, float _y) { super(_x,_y); } 
  void shape() {
    beginShape(POLYGON);
    vertex(-wid,0);
    vertex(-wid/2,hei);
    vertex(wid/2,hei);
    vertex(wid,0);
    vertex(wid/2,-hei);
    vertex(-wid/2,-hei);
    vertex(-wid,0);
    endShape();
  }
}

class ConfettiStar extends ConfettiBase {
  ConfettiStar(float _x, float _y) { super(_x,_y); } 
  void shape() {
    beginShape(POLYGON);
    vertex(-wid/2,0);
    vertex(-wid,hei);
    vertex(0,hei/2);
    vertex(wid/2,hei*3/2);
    vertex(wid/2,hei/2);
    vertex(wid*3/2,0);
    vertex(wid/2,-hei/2);
    vertex(wid/2,-hei*3/2);
    vertex(0,-hei/2);
    vertex(-wid,-hei);
    vertex(-wid/2,0);
    endShape();
  }
}

class ConfettiBoomerang extends ConfettiBase {
  ConfettiBoomerang(float _x, float _y) { super(_x,_y); } 
  void shape() {
    beginShape(POLYGON);
    vertex(0,hei/2);
    vertex(-wid,hei);
    vertex(wid,hei/2);
    vertex(wid,-hei/2);
    vertex(-wid,-hei);
    vertex(0,-hei/2);
    vertex(0,hei/2);
    endShape();
  }
}

class ConfettiShuriken extends ConfettiBase {
  ConfettiShuriken(float _x, float _y) { super(_x,_y); } 
  void shape() {
    beginShape(POLYGON);
    vertex(-wid*3/2,0);
    vertex(0,hei/2);
    vertex(0,hei*3/2);
    vertex(wid/2,0);
    vertex(wid*3/2,0);
    vertex(0,-hei/2);
    vertex(0,-hei*3/2);
    vertex(-wid/2,0);
    vertex(-wid*3/2,0);
    endShape();
  }
}

class MultiPalette {
  PImage img;
  int numPalettes, curPalette;
  MultiPalette(String filename) {
    img = loadImage(filename);
    numPalettes = img.height / 10;
    curPalette = 0;
  }
  void select() {
    curPalette = int(random(numPalettes));
  }
  color get() {
    return img.get(int(random(img.width)), curPalette*10+int(random(10)));
  }
}