// Support.pde (part of Cubicles)
// Dave Bollinger, Sep 2006
// http://www.davebollinger.com
// for Processing 0115 Beta

class Grid {
  char [][] grid;
  int width, height, margin;
  Grid(int w, int h, int m) {
    margin = m;
    width = w+margin*2;
    height = h+margin*2;
    grid = new char[height][width];
    wipe();
  }
  void wipe() {
    for (int y=0; y<height; y++)
      for (int x=0; x<width; x++)
        grid[y][x] = 0;
  }
  void set(int x, int y) {
    x += margin;
    y += margin;
    if ((x>=0) && (y>=0) && (x<width) && (y<height))
      grid[y][x] = 1;
  }
  int get(int x, int y) {
    x += margin;
    y += margin;
    return ((x>=0) && (y>=0) && (x<width) && (y<height)) ? grid[y][x] : 1;
  }
  boolean occupied(float x, float y) {
    return (this.get(int(x), int(y)) != 0);
  }
  void occupy(float x, float y) {
    this.set(int(x), int(y));
  }
}

class MultiPalette {
  PImage img;
  int numPalettes, curPalette;
  MultiPalette(String filename) {
    img = loadImage(filename);
    numPalettes = img.height / 10;
    curPalette = 0;
  }
  void select() {
    curPalette = int(random(numPalettes));
  }
  color get() {
    return img.get(int(random(img.width)), curPalette*10+int(random(10)));
  }
}