// collide() pits particles against triangles in an all-out grudge match
void collide(float dt) {

  // WORKING VECTORS (allocate only once)
  // see "INL:" comments for places where inlining has occurred and alternate syntax
  Vec3 nextpos = new Vec3();
  Vec3 offset = new Vec3();
  
  // TRIANGLE OUTER LOOP
  for (int it=0; it<ntriangles; it++) {
    Triangle tri = (Triangle)triangles.get(it);

    // SETUP WORK FOR TRIANGLE (alias frequenly used members)
    float trid = tri.d;
    Vec3 trinorm = tri.norm, trip1 = tri.p1;
    Vec3 vw = tri.vw, uw = tri.uw;
     
     // PARTICLE INNER LOOP
     for (int ip=0; ip<nparticles; ip++) {
       Particle par = (Particle)particles.get(ip);
   
       // SETUP WORK FOR PARTICLE (alias frequencly used members)
       Vec3 pos=par.pos, vel=par.vel;
       
       // CALCULATE NEXT POSITION OF PARTICLE
       // INL: Vec3 nextpos = pos.add(vel.mul(dt));
       nextpos.x = pos.x + vel.x * dt;
       nextpos.y = pos.y + vel.y * dt;
       nextpos.z = pos.z + vel.z * dt;
  
       // DID PARTICLE PASS THROUGH PLANE?
       float distold = pos.dot(trinorm) + trid;
       float distnew = nextpos.dot(trinorm) + trid;
       if (distold * distnew > 0f) continue; // nope
              
       // CALCULATE DISTANCE TO COLLISION
       float nv = vel.dot(trinorm);
       float ht = -distold / nv;

       // CALCULATE HIT LOCATION
       // INL: Vec3 hit = pos.add(vel.mul(ht));
       float hitx = pos.x + vel.x * ht;
       float hity = pos.y + vel.y * ht;
       float hitz = pos.z + vel.z * ht;

       // CALCULATE OFFSET IN UV COORDS
       // INL: Vec3 offset = hit.sub(trip1);
       offset.x = hitx - trip1.x;
       offset.y = hity - trip1.y;
       offset.z = hitz - trip1.z;

       // DID PARTICLE PASS THROUGH TRIANGLE?
       float upos = offset.dot(vw);
       float vpos = offset.dot(uw);
       if ((upos < 0f) || (vpos < 0f) || (upos+vpos > 1f)) continue; // nope

       // COLLISION RESPONSE
       // INL: Vec3 vnorm = trinorm.mul(nv);
       float vnormx = trinorm.x * nv;
       float vnormy = trinorm.y * nv;
       float vnormz = trinorm.z * nv;
       
       // UPDATE VELOCITY
       // INL: vel.subby(vnorm.mul(2f));
       vel.x -= vnormx * 2f;
       vel.y -= vnormy * 2f;
       vel.z -= vnormz * 2f;
    } // END OF PARTICLE LOOP
  } // END OF TRIANGLE LOOP
}