// WitchHat
// Dave Bollinger, Dec 2006
// http://www.davebollinger.com
// for Processing 0123 Beta

/**
Click and drag to rotate.<br>
Press space to reset particles.<br>
Press 's' to shake particles.<br>
*/

ArrayList particles;
ArrayList triangles;
int nparticles = 100;
color parcolor = color(96,48,24);
color tricolor = color(64,128,64,64);
int trispercone = 12;
int ntriangles;
float rotx=-0.5f, roty=0.26f;
float gravity = 0.1f;
float friction = 0.01f;

void setup() {
  size(300,300,P3D);
  background(255);
  particles = new ArrayList();
  for (int i=0; i<nparticles; i++)
    particles.add(new Particle());
  triangles = new ArrayList();
  populate();  
}

void draw() {
  background(255);
  translate(width/2f, height/2f, 0f);
  rotateX(rotx);
  rotateY(roty);
  simulate();
  render();
}

// populate() creates the "world"
void populate() {
  initParticles();
  makeCone(-40f, 45f, 30f);
  makeCone(40f, 60f, 100f);
  ntriangles = triangles.size();
}

void initParticles() {
  float d = 1f;
  float v = 0.3f;
  for (int i=0; i<nparticles; i++) {
    Particle p = (Particle)particles.get(i);
    p.reset( random(-d,d), -50+random(-d,d), random(-d,d) );
    p.vel.set( random(-v,v), -random(2f,4f), random(-v,v) );
  }
}

void shakeParticles() {
  float d = 1.0f;
  for (int i=0; i<nparticles; i++) {
    Particle p = (Particle)particles.get(i);
    p.vel.addby( random(-d,d), random(-d,d), random(-d,d) );
  }
}

// simulate() runs the physics simulation for one frame
void simulate() {
  // set gravity accelleration
  // (this is currently overkill since nothing else (currently) adjusts accelleration)
  for (int i=0; i<nparticles; i++)
    ((Particle)particles.get(i)).acc.set(0,gravity,0);
  // Euler integrate collision and movement
  float elapsed = 0.0;
  float dt = 0.1;
  do {
    collide(dt);
    for (int i=0; i<nparticles; i++)
      ((Particle)particles.get(i)).integrate(dt);
    elapsed += dt;
  } while (elapsed < 1.0f);
}

// render() draws the world
void render() {
  // render particles
  fill(parcolor);
  noStroke();
  for (int i=0; i<nparticles; i++)
    ((Particle)particles.get(i)).draw();
  // render triangles
  fill(tricolor);
  stroke(32,128);
  for (int i=0; i<ntriangles; i++)
    ((Triangle)triangles.get(i)).draw(); 
}

void keyPressed() {
  if (key==' ') initParticles();
  if (key=='s') shakeParticles();
}

void mouseDragged() {
  rotx += (pmouseY-mouseY) * 0.01f;
  roty += (mouseX-pmouseX) * 0.01f;
}

// triangle-making helper routine
void makeCone(float y1, float y2, float r) {
  Vec3 p1 = new Vec3(0,y1,0);
  Vec3 p2 = new Vec3(0,y2,0);
  Vec3 p3 = new Vec3(0,y2,0);
  float span = TWO_PI / (float)(trispercone);
  for (int i=0; i<trispercone; i++) {
    float theta2 = (float)(i) * span;
    p2.x = r * cos(theta2);
    p2.z = r * sin(theta2);
    float theta3 = (float)(i+1) * span;
    p3.x = r * cos(theta3);
    p3.z = r * sin(theta3);
    triangles.add( new Triangle(p1,p2,p3) );
  }               
}