/**
FeedbackQuads<br>
Dave Bollinger Jun 2007<br>
http://www.davebollinger.com<br>
<br>
Press spacebar to generate new pattern.<br>
<br>
*/

import processing.opengl.*;
import javax.media.opengl.*;

PImage fbimg;

// configuration:
int nquads;
float offset;
float quadsize;
float lrotz, lrotdz;
float grotz, grotdz;

void setup() {
  size(256,256,OPENGL);
  frameRate(10);  
  textureMode(NORMALIZED);
  strokeWeight(4f);
  config();
}

void config() {
  nquads = (int)(random(12))+2;
  offset = random(10,100);
  quadsize = random(40,120);
  lrotdz = random(0,0.1f);
  grotdz = random(0,0.1f); 
  // after a reconfiguration blank the texture image
  fbimg = null;
  fbimg = createImage(width,height,ARGB);
}

void draw() {
  background(0);
  camera();
  
  // draw the feedback background
  fill(255,245);
  noStroke();
  beginShape(QUADS);
  texture(fbimg);
  vertex(0,0, 0,0);
  vertex(width,0, 1,0);
  vertex(width,height, 1,1);
  vertex(0,height, 0,1);
  endShape();
  
  // keep the colors, just clear depth buffer
  // so that feedback quad doesn't interfere with source quads
  ((PGraphicsOpenGL)g).gl.glClear(GL.GL_DEPTH_BUFFER_BIT);
  
  // draw the new source material quads with recursive texture
  fill(255);
  stroke(255);
  translate(width/2, height/2, 100);
  float templrotz = lrotz;
  for (int i=0; i<nquads; i++) {
    pushMatrix();
    float theta = (float)(i) / (float)(nquads) * TWO_PI;
    float x = offset * cos(theta);
    float y = offset * sin(theta);
    rotateZ(grotz);
    translate(x,y); // translation
    rotateZ(templrotz); // local rotation
    rotateY(-0.5); // tilt right size
    templrotz += TWO_PI / (float)(nquads);
    texturedQuad(quadsize);
    popMatrix();
  }
  // update the animation
  lrotz += lrotdz;
  grotz += grotdz;
  // acquire the new feedback texture
  fbimg = null;
  fbimg = get();
}

void texturedQuad(float quadsize) {
  float half = quadsize * 0.5f;
  beginShape(QUADS);
  texture(fbimg);
  vertex(-half,-half, 0,0);
  vertex(half,-half, 1,0);
  vertex(half,half, 1,1);
  vertex(-half,half, 0,1);
  endShape();
}

void keyPressed() {
  if (key==' ') config();
}