// Magnattractor
// Dave Bollinger, August 2006
// http://www.davebollinger.com
// for Processing 0109 Beta

/**
Press 'c' to toggle color/monochrome mode.<br>
Click mouse to advance to next set of parameters.<br>
*/

AttractorSystem attsys;
int nframes;
boolean bColorMode = true;

void setup() {
  size(300,300,P3D);
  framerate(30);
  colorMode(HSB);
  attsys = new AttractorSystem(10);
  next();
}

void next() {
  background(#ffffff);
  attsys.create();
  nframes = 0;
}
  
void draw() {
  attsys.iterate(5,50,500);
  if (++nframes > 1000)
    next();
}

void keyPressed() {
  if (key=='`') saveFrame("frame.tga");
  if (key=='c') {
    bColorMode = !bColorMode;
    if (bColorMode) {
      colorMode(HSB);
      // let individual points set stroke color
    } else {
      colorMode(RGB);
      // set global stroke color
      stroke( color(0,0,0,8) );
    }
  }
}

void mousePressed() {
  next();
}

/*
 *
 * AttractorSystem
 * consists of an attractor and a control point
 *
 */
class AttractorSystem {
  Attractor at;
  ControlPoint cp;
  Extent ex;
  AttractorSystem(int nm) {
    at = new Attractor(nm);
    cp = new ControlPoint();
    ex = new Extent(); 
  }
  void create() {
    do {
      at.create();
      estimate(10,10,100);
    } while (!valid());
  }
  // determine approximate extent of system
  void estimate(int ncp, int nprime, int niters) {
    ex.untrack();
    for (int i=0; i<ncp; i++) {
      cp.create();
      for (int j=0; j<nprime; j++) {
        at.apply(cp);
      }
      for (int j=0; j<niters; j++) {
        at.apply(cp);
        ex.track(cp.x,cp.y,0.02);
      }
    }
  }
  boolean valid() {
    if (!ex.valid()) return false;
    if ((ex.width < 1.0) || (ex.height < 1.0)) return false;
    return true;
  }
  void iterate(int ncp, int nprime, int niters) {
    for (int i=0; i<ncp; i++) {
      cp.create();
      for (int j=0; j<nprime; j++) {
        at.apply(cp);
      }
      for (int j=0; j<niters; j++) {
        at.apply(cp);
        cp.draw(ex);
      }
    }
  }
}

/*
 *
 * a control point that an attractor can apply itself to
 *
 */
class ControlPoint {
  float x, y;
  float ox,oy;
  ControlPoint() {
    create();
  }
  void create() {
    ox = x = random(-1.0,1.0);
    oy = y = random(-1.0,1.0);
  }
  void draw(Extent ex) {
    float scrx = (x - ex.minx) * (width / ex.width);
    float scry = (y - ex.miny) * (height / ex.height);
    if (bColorMode) {
      float h = (atan2(y-oy, x-ox) + PI) / TWO_PI * 255.0;
      stroke( color(h, 224, 96, 8) );
    }
    point(scrx, scry);
  }
} 

/*
 *
 * Attractor
 * wraps up all coefficients that make up the attractor
 *
 */  
class Attractor {
  float [] xs;
  float [] ys;
  float [] rs;
  int nmagnets;
  Attractor(int n) {
    nmagnets = n;
    xs = new float[nmagnets]; 
    ys = new float[nmagnets];
    rs = new float[nmagnets];
    create();
  }  
  void create() {
    for (int i=0; i<nmagnets; i++) {
      xs[i] = random(-0.95,0.95);
      ys[i] = random(-0.95,0.95);
      rs[i] = random(0.01, 0.1);
    }
  }
  void apply(ControlPoint cp) {
    float x=cp.x, y=cp.y;
    float xp=0.0, yp=0.0;
    for (int i=0; i<nmagnets; i++) {
      float dx = xs[i] - cp.x;
      float dy = ys[i] - cp.y;
      float dis = dx*dx + dy*dy;
      if (i%2==0) {
        xp += rs[i] * dx / dis;
        yp += rs[i] * dy / dis;
      } else {
        yp += rs[i] * dx / dis;
        xp += rs[i] * dy / dis;
      }
    }
    cp.ox = cp.x;
    cp.oy = cp.y;
    cp.x = xp;
    cp.y = yp;
  }
}

class Extent {
  float minx,miny,maxx,maxy;
  float width, height;
  Extent() {
  }
  Extent(float _minx, float _miny, float _maxx, float _maxy) {
    minx = _minx; miny = _miny;
    maxx = _maxx; maxy = _maxy;
  }
  void calc() {
    width = maxx - minx;
    height = maxy - miny;
  }
  void untrack() {
    minx = miny = 99;
    maxx = maxy = -99;
  }
  void track(float x, float y, float trackrate) {
    /* hard track:
    if (x < minx) minx = x;
    if (x > maxx) maxx = x;
    if (y < miny) miny = y;
    if (y > maxy) maxy = y;
    */
    /* soft track: */
    if (x < minx) minx += (x-minx) * trackrate;
    if (x > maxx) maxx += (x-maxx) * trackrate;
    if (y < miny) miny += (y-miny) * trackrate;
    if (y > maxy) maxy += (y-maxy) * trackrate;
    calc();
  }
  boolean valid() {
    calc();
    if ((minx <= -1E4) || (miny <= -1E4)) return false;
    if ((maxx >= 1E4) || (maxy >= 1E4)) return false;
    return true;
  }
}