// NounVerber
// Dave Bollinger, Jan 2006
// http://www.davebollinger.com
// updated for Processing 0109 Beta

/**
Click mouse to generate next title...<br>
't' toggles letter color tinting on/off<br>
*/

ScreenFader fader;
StarField starfield;
CoinSlot coinslot;
FlyingTitle title;
String [] nounList;
String [] verbList;
boolean bColorTint = true;

void setup() {
  size(224,288); 
  background(#000033);
  fader = new ScreenFader(0,0,51,32);
  starfield = new StarField(1000);
  coinslot = new CoinSlot("coinslot.gif");
  BitmapFont font = new BitmapFont("envyfont.gif", 26, 'A', 32, 24);
  title = new FlyingTitle(font, "NOUN", "VERBER");
  nounList = loadStrings("nounlist.txt");
  verbList = loadStrings("verblist.txt");
}

void draw() {
  fader.draw();
  starfield.draw();
  coinslot.draw();
  title.draw(bColorTint);
}

void keyPressed() {
  if (key=='`') saveFrame("frame.tga");
  if (key=='t') bColorTint=!bColorTint;
}

void mousePressed() {
  String noun = nounList[(int)random(nounList.length)].toUpperCase();  
  String verber = verbList[(int)random(verbList.length)].toUpperCase(); 
  title.create(noun, verber);
}

/*
 * ScreenFader - handles clearing the screen
 */
class ScreenFader {
  color c;
  ScreenFader(int r, int g, int b, int a) {
    c = color(r,g,b,a);
  }
  void draw() {
    fill(c);
    noStroke();
    rect(0,0,width,height);
  }  
}

/*
 * FlyingTitle - manages the collection of FlyingLetter's
 */
class FlyingTitle {
  static final int nletters = 10;
  FlyingLetter [] letters;
  int currentHue = 0;
  FlyingTitle(BitmapFont font, String noun, String verber) {
    letters = new FlyingLetter[nletters];
    for (int i=0; i<nletters; i++)
      letters[i] = new FlyingLetter(font);
    create(noun, verber); 
  }
  void create(String noun, String verber) {
    int [] targetxs = { 48,80,112,144, 16,48,80,112,144,176 };
    int [] targetys = { 80,80,80,80, 176,176,176,176,176,176 };
    String nounverber = noun + verber;
    for (int i=0; i<nletters; i++)
      letters[i].create(nounverber.charAt(i), targetxs[i], targetys[i]);
  }
  void draw(boolean bTint) {
    if (bTint) colorMode(HSB);
    for (int i=0; i<nletters; i++) {
      if (bTint) {
        tint(currentHue, 224, 224);
        currentHue = (currentHue + 77) & 255;
      }
      letters[i].draw();
    }
    if (bTint) noTint();
  }
}

/*
 * FlyingLetter - a single letter in a FlyingTitle
 */
class FlyingLetter {
  char letter;
  int targetx, targety, dx, dy;
  float t;
  BitmapFont font;
  FlyingLetter(BitmapFont bf) {
    font = bf;
  }
  void create(char ltr, int targx, int targy) {
    letter = ltr;
    targetx = targx;
    targety = targy;
    t = 1.0;
    float theta = random(TWO_PI);
    dx = (int)(cos(theta) * width);
    dy = (int)(sin(theta) * height);
  }
  void draw() {
    if (t > 0.0) t -= 0.02;
    if (t < 0.0) t = 0.0;
    int x = targetx - (int)(t * dx);
    int y = targety - (int)(t * dy);
    font.draw(letter, x, y);
  }
}
 
/*
 * BitmapFont - manages images of bitmap characters
 */
class BitmapFont {
  PImage [] images;
  int nchars, firstchar;
  BitmapFont(String filename, int n, int f, int w, int h) {
    nchars = n;
    firstchar = f;
    images = new PImage[nchars];
    PImage temp = loadImage(filename);
    for (int i=0; i<nchars; i++)
      images[i] = temp.get(i*w,0,w,h);
    temp = null;
  }
  void draw(char c, int x, int y) {
    int i = (int)c - firstchar;
    if ((i>=0) && (i<nchars))
      image(images[i], x, y);
  }
}

/*
 * CoinSlot - manages the coin slot display
 */
class CoinSlot {
  PImage img;
  int ticks;
  CoinSlot(String filename) {
    img = loadImage(filename);
    ticks = 0;
  }
  void draw() {
    if ((++ticks&31)==0)
      image(img, (width-img.width)/2, height-img.height*2);
  }    
}

/*
 * StarField - manages a collection of Star's
 */
class StarField {
  Star [] stars;
  StarField(int n) {
    stars = new Star[n];
    for (int i=0; i<stars.length; i++)
      stars[i] = new Star();
  }
  void draw() {
    noStroke();
    for (int i=0; i<stars.length; i++)
      stars[i].draw();
  }
}

/*
 * Star - a single dot in a StarField
 */        
class Star {
  static final float maxz = 50.0;
  float x, y, z, dz;
  Star() {
    create(); // except..
    z = random(0.0,maxz);
  }
  void create() {
    x = random(-1.0,1.0) * width;
    y = random(-1.0,1.0) * height;
    z = random(0.9,1.0)*maxz;
    dz = random(-0.1,-0.05);
  }
  void draw() {
    z += dz;
    if (z <= 0.0) create();
    int sx = (int)(width * 0.5 + x / z);
    int sy = (int)(height * 0.5 + y / z);
    if ((sx<0) || (sy<0) || (sx>=width) || (sy>=height)) {
      create();
    } else {
      fill((int)((1.0-z/maxz)*255.0));
      rect(sx,sy,1,1);
    }
  }
}