/**
Cat Disintegrator<br>
Dave Bollinger, Feb 2006<br>
http://www.davebollinger.com<br>
For Processing 0109 Beta<br>
<br>
click to explode the cat<br>
multiple clicks will increase complexity<br>
(further exploding an already exploding cat)<br>
then once it's going real good, watch it as it settles<br>
Moire patterns for free<br>
*/

float ctrx, ctry; // screen center
PImage tex; // texture image
Particle [] parties;
int nparties;

void setup() { 
  size(300, 300, P3D);
  ctrx = width / 2f;
  ctry = height / 2f;
  tex = loadImage("fasa100.jpg");
  nparties = tex.width * tex.height;
  parties = new Particle[nparties];
  int idx = 0;
  for (int y=0; y<100; y++) {
    for (int x=0; x<100; x++) {
      parties[idx] = new Particle(x-50, y-50, tex.pixels[idx]);
      idx++;
    }
  }
} 

void mousePressed() {
  float mx = mouseX - ctrx;
  float my = mouseY - ctry;
  float mz = 0f;
  for (int i=0; i<nparties; i++) {
    Particle p = parties[i];
    float dx = p.x - mx;
    float dy = p.y - my;
    float dz = p.z - mz;
    float dis = sqrt(dx*dx+dy*dy+dz*dz);
    if (dis > 0f) {
      float acc = 10f / dis;
      p.impulse(dx*acc, dy*acc, dz*acc);
    }
  }
}

void draw() { 
  background(0);
  translate(ctrx, ctry, 0);
  for (int i=0; i<nparties; i++)
    parties[i].draw();
} 
 
class Particle {
  float ox, oy, oz; // origin position
  float x, y, z; // current position
  float vx, vy, vz; // velocity
  color c;
  static final float friction = 0.97;
  static final float scrunch = 0.01;
  Particle(float x, float y, color c) {
    this.ox = this.x = x;
    this.oy = this.y = y;
    this.oz = this.z = 0f;
    this.c = c;
  }
  void impulse(float ax, float ay, float az) {
    vx += ax;
    vy += ay;
    vz += az;
  }
  void draw() {
    vx += (ox - x) * scrunch;
    vy += (oy - y) * scrunch;
    vz += (oz - z) * scrunch;
    x += vx;
    y += vy;
    z += vz;
    vx *= friction;
    vy *= friction;
    vz *= friction;
/*
    // better quality, but slower:
    noStroke();
    fill(c);
    pushMatrix();
    translate(x, y, z);
    rect(0,0,1,1);
    popMatrix();
*/
    stroke(c);
    point(x, y, z);
  }
}