/**
 PaletteMaker<br>
 Dave Bollinger, Jun 2006<br>
 http://www.davebollinger.com<br>
 updated as of Processing 0123 Beta<br>
 <br>
 Purpose: create a 256-color palette from a larger image by tracing a curve through the image.<br>
 Why:  to then use that palette image as a source of colors for some other project.<br>
 Source image is shown at top, resulting palette is shown at bottom.<br>
 <br>
 Click mouse within upper image to redefine a point on the curve.<br>
 The larger square is the curve point that is currently active.<br>
 4 points/clicks are required to completely redefine the curve.<br>
 <br>
 If it still doesn't make sense, just click 4 points at random and see what happens.<br>
 <br>
 Press ',' and '.' to decrease/increase palette blur.<br>
 Press 's' to save palette image (assumes you're running this locally, not on web!)<br>
 <br>
 Sample results (all from the same demo image):<br><br>
 <img src="pal1.jpg" width="256" height="10" border="0"><br><br>
 <img src="pal2.jpg" width="256" height="10" border="0"><br><br>
 <img src="pal3.jpg" width="256" height="10" border="0"><br><br>
 <img src="pal4.jpg" width="256" height="10" border="0"><br><br>
*/

Texture tex;
Curve crv;
Palette pal;
int blurAmount=3;

void setup() {
  size(256,280);
  tex = new Texture(this, "fruit.jpg"); // derived from pdphoto.org
  crv = new Curve(this);
  pal = new Palette(this);
  createPalette();
  noLoop();
}

void draw() {
  background(0);
  tex.draw();
  crv.draw(0, 0);
  pal.draw(0, 270, 1, 10);
}

void createPalette() {
  pal.scrape(tex, crv);
  for (int i=0; i<blurAmount; i++)
    pal.blur();
}

void keyPressed() {
  if (key=='s') {
    pal.save("palette.jpg", 0, 270, 256, 10);
  }
  if (key=='.') {
    if (++blurAmount > 10)
      blurAmount = 10;
    println("blurAmount = " + blurAmount);
    createPalette();
    redraw();
  }
  if (key==',') {
    if (--blurAmount < 0)
      blurAmount = 0;
    println("blurAmount = " + blurAmount);
    createPalette();
    redraw();
  }
}

void mousePressed() {
  if (mouseButton==RIGHT) return;
  if ((mouseX>=0) && (mouseX<256) && (mouseY>=0) && (mouseY<256)) {
    println("Setting curve point " + crv.cindex + " to " + mouseX + ", " + mouseY);
    crv.set(mouseX, mouseY);
    createPalette();
    redraw();
  }
}