// Classes.pde (part of Perly Burly)
// Dave Bollinger, Dec 2006
// http://www.davebollinger.com
// for Processing 0123 Beta

class Particle {
  float x, y, vx, vy;
  float r, g, b, a, da;
  Particle() { }
  void create() {
    x = random(-1f,1f);
    y = random(-1f,1f);
    vx = vy = 0f;
    color c = pal.get();
    r = red(c);
    g = green(c);
    b = blue(c);
    a = random(0.9f,1.0f);
    da = random(0.005f,0.02f);
  }
  void draw() {
    noisefield.apply(this);
    a -= da;
    x += vx;
    y += vy;
    if ((x<-1f) || (y<-1f) || (x>1f) || (y>1f) || (a<0f))
      create();
    color c = color(r, g, b, (1f-a*a)*64f);
    plot(ctrx+x*ctrx, ctry+y*ctry, c);
  }
}

class NoiseField {
  float [] noisezx;
  float [] noisezy;
  float [] noisescale;
  float [] rates;
  float squeeze;
  float friction;
  int nfields;
  NoiseField(int nf) {
    noiseDetail(3);
    nfields = nf;
    noisezx = new float[nfields]; 
    noisezy = new float[nfields]; 
    noisescale = new float[nfields];
    rates = new float[nfields];
    create();
  }
  void create() {
    for (int i=0; i<nfields; i++) {
      noisezx[i] = random(-100f,100f);
      noisezy[i] = random(-100f,100f);
      noisescale[i] = random(1f,10f);
      rates[i] = random(0.0001,0.001);
    }
    squeeze = random(0.99,0.999);
    friction = random(0.9,0.99);
  }
  void apply(Particle p) {
    for (int i=0; i<nfields; i++) {
      float px = p.x * noisescale[i];
      float py = p.y * noisescale[i];
      float nx = noise(px, py, noisezx[i]) * 2.0 - 1.0;
      float ny = noise(px, py, noisezy[i]) * 2.0 - 1.0;
      p.vx += nx * rates[i];
      p.vy += ny * rates[i];
    }
    p.vx *= friction;
    p.vy *= friction;
    p.x *= squeeze;
    p.y *= squeeze;
  }
}

class MultiPalette {
  PImage img;
  int numPalettes, curPalette;
  MultiPalette(String filename) {
    img = loadImage(filename);
    numPalettes = img.height / 10;
    curPalette = 0;
  }
  void select() {
    curPalette = int(random(numPalettes));
  }
  color get() {
    return img.get(int(random(img.width)), curPalette*10+int(random(10)));
  }
}