// TrackerChase01 (a group of trackers, first follows mouse, rest follow each other)
// David Bollinger, January 2006
// http://www.davebollinger.com
// for Processing 0015 Beta
//

// first tracker follows mouse, rest follows first
class TrackerChase {
  int ntrackers;
  Tracker [] trackers;
  TrackerChase(int n) {
    ntrackers = n;
    trackers = new Tracker[ntrackers];
    for (int i=0; i<ntrackers; i++) {
      trackers[i] = new Tracker();
    }
    setPhysics(0.05, 0.05);
  }
  void setColor(color c) {
    for (int i=0; i<ntrackers; i++)
      trackers[i].setColor(c);
  }
  void setPhysics(float rate, float friction) {
    for (int j=0; j<ntrackers; j++) {
      int i = ntrackers - 1 - j;
      trackers[j].setPhysics((0.01+i*0.01)*3*rate, (0.01+i*0.01)*10*friction);
    }
  }
  void setTarget(float x, float y) {
    trackers[0].setTarget(x,y);
    for (int i=1; i<ntrackers; i++)
      trackers[i].setTarget(trackers[i-1].x, trackers[i-1].y);
  }
  void move(float dt) {
    for (int i=0; i<ntrackers; i++)
      trackers[i].move(dt);
  }
  void draw() {
    for (int i=0; i<ntrackers; i++)
      trackers[i].draw();
  }
}  

TrackerChase trackerchase;
HScrollbar hsr;
HScrollbar hsf;

boolean isDrawing = false;
float timeslice = 0.1;
boolean bGotMouse = false;
color bgcolor = #ffffff;
color fgcolor = color(8,32,128,32);

void setup() {
  size(480,480,P3D);
  background(bgcolor);

  trackerchase = new TrackerChase(50);
  trackerchase.setColor(fgcolor);
  
  PFont font = loadFont("small-6.vlw");
  hsr = new HScrollbar(10, height-20, 100, 8, 5, "RATE", font);
    hsr.setRange(0.01,0.1);
    hsr.setValue(0.05);
  hsf = new HScrollbar(10, height-8, 100, 8, 5, "FRICTION", font);
    hsf.setRange(0.01,0.1);
    hsf.setValue(0.05);
  // in general (friction >= rate) is a "better" mouse follower
}

void draw() {
  hsr.update(); 
  hsf.update();   
  trackerchase.setPhysics(hsr.getValue(), hsf.getValue());
  
  boolean localGotMouse = bGotMouse;
  if (hsr.over || hsf.over)
    localGotMouse = false;
  
  if (localGotMouse) {
    float targetx = (float)(mouseX);
    float targety = (float)(mouseY);
    trackerchase.setTarget(targetx, targety);
    float elapsed = 0.0;
    while (elapsed < 1.0) {
      trackerchase.move(timeslice);
      if (isDrawing)
        trackerchase.draw();
      elapsed += timeslice;
    } 
  }
  
  hsr.draw();
  hsf.draw();
}  

void mousePressed() {
  bGotMouse = true;
  if (mouseButton == LEFT) {
    isDrawing = true;
  }
  else
  if (mouseButton == RIGHT) {
    background(bgcolor);
  }
}

void mouseReleased() {
  if (mouseButton == LEFT) {
    isDrawing = false;
  }
}

void keyPressed() {
  if (key=='s') saveFrame("frame.tga");
}