// TrackerPack01 (a whole pack of trackers)
// David Bollinger, January 2006
// http://www.davebollinger.com
// for Processing 0015 Beta
//

// many trackers follow mouse at different rates
class TrackerPack {
  int ntrackers;
  Tracker [] trackers;
  TrackerPack(int n) {
    ntrackers = n;
    trackers = new Tracker[ntrackers];
    for (int i=0; i<ntrackers; i++) {
      trackers[i] = new Tracker();
      trackers[i].setPhysics(0.01+i*0.01, 0.01+i*0.01);
    }
  }
  void setColor(color c) {
    for (int i=0; i<ntrackers; i++)
      trackers[i].setColor(c);
  }
  void setPhysics(float rate, float friction) {
    for (int i=0; i<ntrackers; i++)
      trackers[i].setPhysics((0.01+i*0.01)*10*rate, (0.01+i*0.01)*10*friction);
  }
  void setTarget(float x, float y) {
    for (int i=0; i<ntrackers; i++)
      trackers[i].setTarget(x, y);
  }
  void move(float dt) {
    for (int i=0; i<ntrackers; i++)
      trackers[i].move(dt);
  }
  void draw() {
    for (int i=0; i<ntrackers; i++)
      trackers[i].draw();
  }
}  

TrackerPack trackerpack;
HScrollbar hsr;
HScrollbar hsf;

boolean isDrawing = false;
float timeslice = 0.1;
boolean bGotMouse = false;
color bgcolor = #ffffff;
color fgcolor = color(8,32,128,32);

void setup() {
  size(480,480,P3D);
  background(bgcolor);

  trackerpack = new TrackerPack(50);
  trackerpack.setColor(fgcolor);
  
  PFont font = loadFont("small-6.vlw");
  hsr = new HScrollbar(10, height-20, 100, 8, 5, "RATE", font);
    hsr.setRange(0.01,0.1);
    hsr.setValue(0.05);
  hsf = new HScrollbar(10, height-8, 100, 8, 5, "FRICTION", font);
    hsf.setRange(0.01,0.1);
    hsf.setValue(0.05);
  // in general (friction >= rate) is a "better" mouse follower
}

void draw() {
  hsr.update(); 
  hsf.update();   
  trackerpack.setPhysics(hsr.getValue(), hsf.getValue());
  
  boolean localGotMouse = bGotMouse;
  if (hsr.over || hsf.over)
    localGotMouse = false;
  
  if (localGotMouse) {
    float targetx = (float)(mouseX);
    float targety = (float)(mouseY);
    trackerpack.setTarget(targetx, targety);
    float elapsed = 0.0;
    while (elapsed < 1.0) {
      trackerpack.move(timeslice);
      if (isDrawing)
        trackerpack.draw();
      elapsed += timeslice;
    } 
  }
  
  hsr.draw();
  hsf.draw();
}  

void mousePressed() {
  bGotMouse = true;
  if (mouseButton == LEFT) {
    isDrawing = true;
  }
  else
  if (mouseButton == RIGHT) {
    background(bgcolor);
  }
}

void mouseReleased() {
  if (mouseButton == LEFT) {
    isDrawing = false;
  }
}

void keyPressed() {
  if (key=='s') saveFrame("frame.tga");
}